* RMatch1965y2001control.sps.
* Match patients with teeth filled in March 2000 against other
* teeth treated in year ending March 2001.
* Written by PSKL on 28/11/01.

* Restrict March 2000 data to fillings.

get file = 'D:\PSKL\Rteeth196510003to10103.sav'.

select if ( fsched = 10003).

select if ( any( trtcode, 1401,1402,1403,1404,1421,1426)).

* save master file of filled teeth (temp1).

Compute Fillrec=1.

save outfile='c:\temp1.sav'.

get file='c:\temp1.sav'.

* save look-up table, one record for each tooth, for matching (temp2).

Compute Filled=1.

sort cases by surname initial sex dobirth tooth quadrant doacc docomp.

Aggregate outfile=* /presorted
 /break surname initial sex dobirth tooth quadrant
 /filled =max(filled)
 /dofacc dofcomp=first(doacc docomp).

save outfile= 'c:\temp2.sav'
 / keep surname initial sex dobirth tooth quadrant filled dofacc dofcomp.

* Create lookup file of patients who have had fillings in March 2000 (temp2A).
* This file contains a dummy quadrant to indicate that at least one tooth in
* the tooth position has been filled.

Aggregate outfile=*/presorted
 /break surname initial sex dobirth tooth
 /dofacc dofcomp=first(dofacc dofcomp).
compute doacc=dofacc.
compute docomp=dofcomp.

string quadrant (A2).
compute quadrant='AA'.

compute fillrec=-1.

save outfile='c:\temp2a.sav'.


* Match against quadrant records for next year, but exclude correction records.

get file = 'D:\PSKL\Rteeth196510003to10103.sav'.

sort cases by surname initial sex dobirth tooth quadrant doacc.

Match files file=*
 /table 'c:\temp2a.sav'
 /by surname initial sex dobirth tooth.

Execute.

select if (not(missing(dofacc)) and not(dofacc=doacc)).

Compute fillrec=0.

Execute.

* Remove quadrants which had fillings in March 2000.

Match files file=*
 /table='c:\temp2.sav'
 /by surname initial sex dobirth tooth quadrant.

If (missing(filled)) filled=0.
select if (filled=0).

Execute.

* Combine with March 2000 dummy quadrant records, when patients received fillings
 in at least one quadrant, to get dates of March 2000 courses of treatment.

Add files file= 'C:\temp2a.sav'
 /file *
 /by surname initial sex dobirth tooth quadrant fillrec.

* Remove additional fee records.

If (missing(trtcode)) trtcode=0.
select if not (range(trtcode,1431,1431,1422,1425,1541,1541,
   1732,1739,1811,1816,2746,2746,5825,5825)).

save outfile='c:\temp3.sav'.

get file='c:\temp3.sav'.

* Reduce to file of teeth not filled in March 2000 schedule but
* where other teeth in the same position were treated then, but treated in following year,
* supplemented by time to failure and
* replacement treatment.

sort cases by surname initial sex dobirth tooth quadrant fillrec doacc trtcode.

aggregate outfile=*
 /presorted
 /break surname initial sex dobirth tooth quadrant fillrec doacc
 / fpcnum persnum partnum suffix postcode docomp exempbox
   trtcode quadcode toothpat exempcod =
 first(fpcnum persnum partnum suffix postcode docomp exempbox
   trtcode quadcode toothpat exempcod)
 /t1=first(trtcode)
 /t2=sum(trtcode)
 /t3=last(trtcode)
 /treats=n.

EXECUTE.

* Calculate time lag for each replacement treatment - up to three per patient.
Do if (fillrec=0 and lag(fillrec)=-1).
compute time=ctime.days(doacc-lag(docomp)).
compute reptrt1=t1.
if (treats=2) reptrt2=t3.
if (treats=3) reptrt2=t2-t1-t3.
if (treats=3) reptrt3=t3.
Compute reptreat=reptrt1.
If (treats>1) reptreat=9999.
End if.

Do if (fillrec=0 and lag(fillrec,2)=-1).
compute time=ctime.days(doacc-lag(docomp,2)).
compute reptrt1=t1.
if (treats=2) reptrt2=t3.
if (treats=3) reptrt2=t2-t1-t3.
if (treats=3) reptrt3=t3.
Compute reptreat=reptrt1.
If (treats>1) reptreat=9999.
End if.

Do if (fillrec=0 and not(lag(fillrec))=-1 and lag(fillrec,3)=-1).
compute time=ctime.days(doacc-lag(docomp,3)).
compute reptrt1=t1.
if (treats=2) reptrt2=t3.
if (treats=3) reptrt2=t2-t1-t3.
if (treats=3) reptrt3=t3.
Compute reptreat=reptrt1.
If (treats>1) reptreat=9999.
End if.

formats trtcode reptreat (f4.0).
formats trtcode reptreat (f4.0) tooth (f1.0).

EXECUTE.

* Tidy up the remaining anomalies.
* Assume negative time cases reflect claims out of sequence.
* Censor all cases at 365 days.
Compute failed=0.
Do if (range(time,1,365)).
compute failed=1.
else.
compute time=365.
end if.
If (missing(time))time=365.

EXECUTE.

* Reduce to one record, for the first retreatment,
* for each quadrant for which the tooth was not treated in March 2000,
* including a dummy quadrant record if the tooth was not retreated.

sort cases by surname initial sex dobirth tooth quadrant time.

Aggregate outfile=* /presorted
 /break surname initial sex dobirth tooth quadrant
 / doacc fpcnum persnum partnum suffix postcode docomp
   exempbox trtcode exempcod time reptreat reptrt1 reptrt2 reptrt3 failed
 =first(doacc fpcnum persnum partnum suffix postcode docomp
   exempbox trtcode exempcod time reptreat reptrt1 reptrt2 reptrt3 failed).

save outfile='D:\pskl\RMatch1965y2001control.sav'.

Get file='D:\pskl\RMatch1965y2001control.sav'.


* Produce some tables.

* a) Proportion of early failures, by tooth position, quadrant, type of filling, and patient sex.

Compute failedPC=100*failed.

autorecode VARIABLES= quadrant sex
 /INTO quadn sexn.

Value Labels
 Tooth TRTCODE
1 '1'
2 '2'
3 '3'
4 '4'
5 '5'
6 '6'
7 '7'
8 '8'
1401 '1401'
1402 '1402'
1403 '1403'
1404 '1404'
1421 '1421'
1426 '1426'.

Variable Labels Tooth 'Tooth Position'
 /quadrant quadn 'Quadrant'
 /trtcode 'Treatment Code'.

Temporary.
select if (any(quadrant,'LL','AA')).

* Basic Tables.
TABLES
  /FORMAT BLANK MISSING('.')
  /OBSERVATION failedpc
  /FTOTAL $t 'Summary'
  /TABLES (sexn > failedpc +  $t )
  BY (tooth +  $t )
  BY ((STATISTICS))
  /STATISTICS
  mean( (PCT7.2 ))
  count( ( COMMA7.0 )) /TITLE  'Retreatment rates by tooth'+
 ' position and patient sex - LL Quadrant'.

Temporary.
select if (any(quadrant,'LR','AA')).

* Basic Tables.
TABLES
  /FORMAT BLANK MISSING('.')
  /OBSERVATION failedpc
  /FTOTAL $t 'Summary'
  /TABLES (sexn > failedpc +  $t )
  BY (tooth +  $t )
  BY ((STATISTICS))
  /STATISTICS
  mean( (PCT7.2 ))
  count( ( COMMA7.0 )) /TITLE  'Retreatment rates by tooth'+
 ' position and patient sex - LR Quadrant'.

.

Temporary.
select if (any(quadrant,'UL','AA')).

* Basic Tables.
TABLES
  /FORMAT BLANK MISSING('.')
  /OBSERVATION failedpc
  /FTOTAL $t 'Summary'
  /TABLES (sexn > failedpc +  $t )
  BY (tooth +  $t )
  BY ((STATISTICS))
  /STATISTICS
  mean( (PCT7.2 ))
  count( ( COMMA7.0 )) /TITLE  'Retreatment rates by tooth'+
 ' position and patient sex - UL Quadrant'.

Temporary.
select if (any(quadrant,'UR','AA')).

* Basic Tables.
TABLES
  /FORMAT BLANK MISSING('.')
  /OBSERVATION failedpc
  /FTOTAL $t 'Summary'
  /TABLES (sexn > failedpc +  $t )
  BY (tooth +  $t )
  BY ((STATISTICS))
  /STATISTICS
  mean( (PCT7.2 ))
  count( ( COMMA7.0 )) /TITLE  'Retreatment rates by tooth'+
 ' position and patient sex - UR Quadrant'.

* b) Replacement treatment , by quadrant.

string retcomb (a14).
compute retcomb=concat(string( reptrt1,f4),'/',string( reptrt2,f4),'/',string( reptrt3,f4)).

Variable Labels retcomb 'Retreatment combination'.

execute.

temporary.
select if ( failed=1).

CROSSTABS
  /TABLES=retcomb  BY quadrant  BY tooth
  /FORMAT= AVALUE TABLES
  /CELLS= COUNT COLUMN .